  
SetVar version 2.4
SetVar useBMSversion 0
SetVar useCustomizer 0

IfNot DialogYesNo "Willst du \"The Blade of the Haunted - DV - Eine Schwertquest\" (version %version%) installieren?"
	FatalError
EndIf

;** Requirement Check for OBMM 1.1.12 or higher **
If VersionLessThan 1.1.12
   Message "Diese Mod musst mit einer OBMM-Version von mindestens 1.1.12 installiert werden, um Installationsfehlern vorzubeugen%NewLine%Installation wird nun beendet." "WARNUNG - Nicht unterstützte OBMM-Version"
   FatalError
EndIf

;** Requirement Check for Oblivion 1.2.0416 or higher **
IfNot OblivionNewerThan 1.2.0416
   Message "Diese Mod benötigt Oblivion auf Patchstufe 1.2.0416. Bitte lade dir den neuesten offiziellen Patch runter und installiere ihn.%NewLine%Installation wird nun beendet." "WARNUNG - Nicht unterstützte Oblivion-Version"
   FatalError
EndIf

;** Requirement Check for OBSE 19 or higher **
IfNot ScriptExtenderPresent
  IfNot DialogYesNo "Diese Mod benötigt den Oblivion Script Extender (OBSE), welcher nicht entdeckt werden konnte.%NewLine%%NewLine%ANMERKUNG FÜR STEAM-NUTZER:%NewLine%Wenn du eine STEAM-Version von Oblivion nutzt, ist die OBSE-Erkennung nicht immer zuverlässig.%NewLine%Wenn du WIRKLICH sicher bist, dass du die korrekte OBSE-Version nutzt, kannst du die Installation überspringen.%NewLine%Ansonsten wird die Installation abgebrochen.%NewLine%%NewLine%Willst du weiter installieren?" "WARNUNG - OBSE-Erkennung nicht möglich"
	FatalError
  EndIf
EndIf
IfNot ScriptExtenderNewerThan 0.0.18.9 
  IfNot DialogYesNo "Diese Mod benötigt OBSE ab Version 0019. Der OBMM hat eine zu geringe Version entdeckt.%NewLine%%NewLine%ANMERKUNG FÜR STEAM-NUTZER:%NewLine%Wenn du eine STEAM-Version von Oblivion nutzt, ist die OBSE-Erkennung nicht immer zuverlässig.%NewLine%Wenn du WIRKLICH sicher bist, dass du die korrekte OBSE-Version nutzt, kannst du die Installation überspringen.%NewLine%Ansonsten wird die Installation abgebrochen.%NewLine%%NewLine%Willst du weiter installieren?" "WARNUNG - Nicht unterstützte OBSE-Version"	FatalError
  EndIf
EndIf 

;** Requirement Check for ShiveringIsles **
IfNot DataFileExists "DLCShiveringIsles.esp"
  Message "Diese Mod benötigt Shivering Isles, welches nicht erkannt werden konnte.%NewLine%Installation wird nun beendet." "WARNUNG - Shivering Isles fehlt"
  FatalError
EndIf


;** Compatibility Check for CM Partners.esm **
If DataFileExists "CM Partners.esm"
  IfNot DialogYesNo "OBMM hat entdeckt, dass CM-Partners (CM Partners.esm) installiert ist, welche Companions hinzufügt.%NewLine%Wenn du diese Mod nutzt (d.h. wenn sie aktiv ist), solltest du die besonderen Anmerkungen in der ReadMe lesen!%NewLine%%NewLine%Willst du mit der Installation fortfahren?"
  	FatalError
  EndIf
EndIf

;** Install core resources **
DontInstallAnyPlugins
DontInstallAnyDataFiles
CopyDataFile "00 Core\\BladeOfTheHauntedDV - Resources.bsa" "BladeOfTheHauntedDV - Resources.bsa"
CopyDataFile "00 Core\\Music\\BladeOfTheHaunted\\Redemption\\AlysmerasDream.mp3" "Music\\BladeOfTheHaunted\\Redemption\\AlysmerasDream.mp3"
CopyDataFile "00 Core\\Music\\BladeOfTheHaunted\\Redemption\\Silence.mp3" "Music\\BladeOfTheHaunted\\Redemption\\Silence.mp3"

;** Detect whether Better Music System is installed and let the user choose whether he wants to install the compatibility version **
If DataFileExists "BetterMusicSystem.esm"
  Message "OBMM hat entdeckt, dass Better Music System (BetterMusicSystem.esm) installiert ist.%NewLine%Wenn du diese Mod nutzt (d.h. wenn sie aktiv ist), solltest du die BMS-kompatible Version installieren (bitte in der ReadMe für genauere Details nachsehen).%NewLine%%NewLine%Bitte wähle aus, welche Version installiert werden soll."
  SelectWithDescriptions "ESP-Version auswählen" "BetterMusicSystem-kompatible Version" "Diese Version garantiert vollste Kompatibilität mit BMS. Sie läuft NUR, wenn BMS aktiv ist." "Grundversion (kein Better Music System)" "Diese Version läuft mit oder ohne Better Music System, aber mit BMS ist die andere Version empfehlenswerter." "Keine (Installation beenden)" "Das wird die Installation beenden."
  Case BetterMusicSystem-kompatible Version
  	SetVar useBMSversion 1
  	Break
  Case Grundversion (kein Better Music System)
  	SetVar useBMSversion 0
  	Break
  Case Keine (Installation beenden)
  	FatalError
  EndSelect
EndIf

If Equal %useBMSversion% 0
	CopyPlugin "01 Base Version (no Better Music System)\\BladeOfTheHauntedDV.esp" "BladeOfTheHauntedDV.esp"
Else
  	CopyPlugin "01 BetterMusicSystem compatibility\\BladeOfTheHauntedDV.esp" "BladeOfTheHauntedDV.esp"
EndIf

;** Remove the deprecated UL Imperial Isle patch, if present**
If DataFileExists "BladeOfTheHaunted_UL_ImperialIsle_Patch.esp" 
  Message "OBMM hat den veralteten Patch für Unique Landscapes - Imperial Isle installiert ist, welches auf Version 2.2. zugeschnitten war.%NewLine%Bitte entferne diesen nach der Installation unbedingt, weil es nichts mehr bringt und/oder Fehler verursachen wird!"
EndIf

;** Let the user choose whether to use the Blade Customizer feature by default **
If DialogYesNo "Willst du Klingenanpassungen im Spiel vornehmen?%NewLine%%NewLine%Dieses Feature fügt einen Zauber hinzu, welches den Spieler die Werte und die Waffenhaltung wechseln lassen kann. Es kann in der INI-Datei später de- und aktiviert werden"
	SetVar useCustomizer 1
EndIf

If Equal %useCustomizer% 0
	CopyDataFile "02 No Blade Customizer\\BladeOfTheHaunted.ini" "BladeOfTheHaunted.ini"
Else
  	CopyDataFile "02 Blade Customizer\\BladeOfTheHaunted.ini" "BladeOfTheHaunted.ini"
EndIf
 

Message "Installation wird nun beendet (das kann etwas dauern!)%NewLine%Wenn Du Wyre Bash nutzst (was empfohlen wird), vergiss nicht die Fraktionen in den Bashed Patch zu mergen.%NewLine%Wenn du keine 'ArchiveInvalidation Invalidated!' nutzst, vergiss nicht, manuell eine Archive Invalidation vorzunehmen!%NewLine%%NewLine%Frohes Schwertjagen!%NewLine%jaime74 und DarkRuler2500"